-- IDL module extracted from ITU-T Q.834.4 (07/2003)

#ifndef __Q834_4_TRANSFERMGR_DEFINED
#define __Q834_4_TRANSFERMGR_DEFINED

#include "Q834Common.idl"

#pragma prefix "itu.Int"


module q834_4 
{

module FileTransfer
{ 

// begin definitions from other idl files

// From Q834Common

	typedef Q834Common::ManagedEntityIdType ManagedEntityIdType;
	typedef Q834Common::UserLabelType	 UserLabelType;
	typedef Q834Common::StatusValueType StatusValueType;
	typedef Q834Common::DCNAddressType DCNAddressType;
	typedef Q834Common::FilenameType 	FilenameType;
	typedef Q834Common::TransferTrackingObjectIdType	TransferTrackingObjectIdType;
	typedef Q834Common::UserIdType UserIdType;
	typedef Q834Common::PasswordType 	PasswordType;
	typedef Q834Common::GeneralizedTimeType GeneralizedTimeType;

#define AccessDenied Q834Common::AccessDenied
#define CommFailure Q834Common::CommFailure
#define UnknownScheduler Q834Common::UnknownScheduler
#define UnknownDestinationServer Q834Common::UnknownDestinationServer
#define InvalidScheduler Q834Common::InvalidScheduler
#define UnknownRecordSet Q834Common::UnknownRecordSet

// End definitions from other idl files

// Local data types

	
	
	struct FileTransferHistoryType {
	  ManagedEntityIdType recordSetId;
	  DCNAddressType destinationServerAddr;
	  UserIdType	userId;
	  FilenameType destinationFile;
	  GeneralizedTimeType transferTime;
	};
	typedef sequence<FileTransferHistoryType> FileTransferHistorySeqType;
	
	struct ScheduledFileTransferType {
	  ManagedEntityIdType recordSetId;
	  UserLabelType schedulerName;
	};
	typedef sequence<ScheduledFileTransferType> ScheduledFileTransferSeqType;

// Local exceptions 

	exception UnknownTransferProcess {};

// End local definitions


	valuetype TransferMgrValueType: itut_x780::ManagedObjectValueType {
	
		public FileTransferHistorySeqType fileTransferHistoryList; // GET
		public ScheduledFileTransferSeqType scheduledFileTransferList; // GET
	
	};

	interface TransferMgr : itut_x780::ManagedObject {
	
		// See 9.16.1.1 for the description of the behaviour of this operation
		
			TransferTrackingObjectIdType fileTransfer(
				in ManagedEntityIdType recordSetId,
				in DCNAddressType destinationServerAddr,
				in UserIdType userId,
				in PasswordType password,
				in FilenameType destinationFile,
				in boolean overwriteExistingFile)
				raises (AccessDenied,
					CommFailure,
					UnknownRecordSet,
					UnknownDestinationServer
					);
		
				
		// See 9.16.1.2 for the description of the behaviour of this operation
		
			TransferTrackingObjectIdType scheduleFileTransfer(
				in ManagedEntityIdType recordSetId,
				in DCNAddressType destinationServerAddr,
				in UserIdType userId,
				in PasswordType password,
				in FilenameType destinationFile,
				in boolean overwriteExistingFile,
				in UserLabelType schedulerName)
				raises (AccessDenied,
					UnknownRecordSet,
					UnknownDestinationServer,
					UnknownScheduler,
					InvalidScheduler);
		
		// See 9.16.1.3 for the description of the behaviour of this operation
		
		        void modifyFileTransferSchedule(
		        	in TransferTrackingObjectIdType transferTrackingObjectId,
		        	in UserLabelType newSchedulerName)
				raises (AccessDenied,
					UnknownTransferProcess,
					UnknownScheduler,
					InvalidScheduler);

		// See 9.16.1.4 for the description of the behaviour of this operation
		
			void cancelScheduledFileTransfer (
				in TransferTrackingObjectIdType transferTrackingObjectId)
				raises (AccessDenied, 
					UnknownTransferProcess);
	
		// See 9.16.1.5 for the description of the behaviour of this operation
		
			StatusValueType getStatus(
				in TransferTrackingObjectIdType transferTrackingObjectId)
				raises (UnknownTransferProcess,
					AccessDenied);
		        
		// See 9.16.1.6 for the description of the behaviour of this operation
		
		FileTransferHistorySeqType fileTransferHistoryListGet ()
			raises (AccessDenied);
		
		// See 9.16.1.7 for the description of the behaviour of this operation
			
		ScheduledFileTransferSeqType scheduledFileTransferListGet()
			raises (AccessDenied);
		
	}; // interface TransferMgr
	
}; // module FileTransfer

}; // module q834_4

#endif