-- IDL module extracted from ITU-T Q.834.4 (07/2003)

#ifndef __Q834_4_PERFORMANCEMANAGER_DEFINED
#define __Q834_4_PERFORMANCEMANAGER_DEFINED


#include "Q834Common.idl" 

#pragma prefix "itu.Int"

module q834_4 {

module PerformanceManager {

	// begin definitions from other idl files
		
	// From Q834Common	
	typedef Q834Common::NameType NameType;
	typedef Q834Common::ManagedEntityIdType ManagedEntityIdType;
	typedef Q834Common::ManagedEntityIdSeqType ManagedEntityIdSeqType;
	typedef Q834Common::UserLabelType UserLabelType;
	typedef Q834Common::GeneralizedTimeType GeneralizedTimeType;
	typedef Q834Common::RecordSeqType RecordSeqType; 
	typedef Q834Common::ServiceInstanceIdType ServiceInstanceIdType;
	typedef Q834Common::MonitoredParameterType MonitoredParameterType;
	typedef Q834Common::NameSeqType NameSeqType;
	typedef Q834Common::MonitoringKindType MonitoringKindType;
	typedef Q834Common::RecordKindType RecordKindType;

		
	#define AccessDenied Q834Common::AccessDenied
	#define UnknownNE Q834Common::UnknownNE
	#define UnknownManagedEntity Q834Common::UnknownManagedEntity
	#define UnknownProfiles Q834Common::UnknownProfiles
	#define UnknownServiceInstance Q834Common::UnknownServiceInstance  
	#define UnknownScheduler Q834Common::UnknownScheduler
	#define CommFailure Q834Common::CommFailure
	#define InvalidScheduler Q834Common::InvalidScheduler
	#define EquipmentFailure Q834Common::EquipmentFailure
	#define ProfileSuspended Q834Common::ProfileSuspended
	
	// End definitions from other idl files
	
	// Local data types
	
	
	struct  MonitoringPointKindAndThresholdsType {
		MonitoringKindType	monitoringType;
		NameType	thresholdDataProfileName;
	};
	/*
	NOTE – ITU-T Recs Q.834.1 and Q.834.2 describe the relationships between ThresholdData and specific monitoring point types.
	*/

	typedef sequence<MonitoringPointKindAndThresholdsType> ThresholdsSeqType;
	
	struct MonitoringPointAndThresholdsType {
		ManagedEntityIdType monitoringPoint;
		NameType	thresholdDataProfileName;
	};
	
	typedef sequence<MonitoringPointAndThresholdsType> MonitoringPointThresholdsSeqType;
	
	typedef sequence<MonitoredParameterType> MonitoredParameterSeqType;
	
	typedef sequence<RecordSeqType> RecordsSeqType; // Implicitly grouped by record type.
	
	typedef RecordKindType	HistoryDataType; // Values defined in Q834Common::RecordSetType
	
	typedef ManagedEntityIdSeqType MonitoringPointSeqType;
	
	struct SWPValueType {
		ManagedEntityIdType monitoringPoint;
		short totConsecutiveIntvls;
		short persistenceMinimum;
	};
	
	typedef sequence< SWPValueType > SWPValueSeqType;
	
		
	struct ParameterSettingType {
		MonitoredParameterType monitoredParameter;
		short totConsecutiveIntvls;
		short persistenceMinimum;
	};
	
	typedef sequence<ParameterSettingType> ParameterSettingSeqType;
			
	// Local exceptions 
	
	exception UnknownParameters {
		MonitoredParameterSeqType monitoredParameterList;
	};	
	exception IntervalCountTooLarge {};	
	exception UnknownMonitoringPointTypes {
		MonitoringPointSeqType monitoringPointKindList;
	};
	exception InvalidAssociation {};
	exception CollectionPeriodPast {};
	exception CollectionLimitation {};
	exception UnknownHistoryDataType {};
	
	// End local definitions
	
		
	interface ImpairmentPersistence : itut_x780::ManagedObject {
		
		// See 9.8.1.1 for the description of the behaviour of this operation
		
		void setSlidingWindowParameters (
			in ManagedEntityIdType nEManagedEntityId,
			in MonitoredParameterSeqType monitoredParameterList,
			in short totConsecutiveIntvls,
			in short persistenceMinimum,
			in boolean sysScopeInd)
			raises (UnknownNE,
				UnknownParameters,
				IntervalCountTooLarge,
				AccessDenied,
				CommFailure);
		
		// See 9.8.1.2 for the description of the behaviour of this operation
		
		void setSpecificSlidingWindowParameters (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in MonitoredParameterSeqType monitoredParameterList,
			in short totConsecutiveIntvls,
			in short persistenceMinimum,
			in boolean allowGlobalOverwrite)
			raises (UnknownNE,
				UnknownParameters,
				IntervalCountTooLarge,
				AccessDenied,
				UnknownManagedEntity,
				CommFailure,
				EquipmentFailure);
		
		// See 9.8.1.3 for the description of the behaviour of this operation

		SWPValueSeqType getSpecificSlidingWindowParameters (
			in ManagedEntityIdType nEManagedEntityId,
			in MonitoredParameterType monitoredParameter)
			raises (UnknownNE,
				UnknownParameters,
				CommFailure);
		
		// See 9.8.1.4 for the description of the behaviour of this operation
		
		void setThreshold (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in NameType thresholdDataProfileName)
			raises (UnknownNE,
				AccessDenied,
				UnknownManagedEntity,
				UnknownProfiles,
				InvalidAssociation,
				CommFailure,
				ProfileSuspended);

		// See 9.8.1.5 for the description of the behaviour of this operation
		
		void setThresholds (
			in ManagedEntityIdType nEManagedEntityId,
			in boolean sysScopeInd,
			in ThresholdsSeqType thresholdsList)
			raises (UnknownNE,
				UnknownProfiles,
				AccessDenied,
				UnknownMonitoringPointTypes,
				InvalidAssociation,
				CommFailure,
				ProfileSuspended);  
		
		// See 9.8.1.6 for the description of the behaviour of this operation
		
		MonitoringPointThresholdsSeqType getThresholdValues (
			in ManagedEntityIdType nEManagedEntityId,
			in MonitoringKindType monitoringType)
			raises (UnknownNE,
				UnknownMonitoringPointTypes,
				CommFailure);
				
		// See 9.8.1.7 for the description of the behaviour of this operation
		
		ThresholdsSeqType getSystemThresholdsSetting(
			in ManagedEntityIdType nEManagedEntityId)
			raises (AccessDenied, UnknownManagedEntity);
		
		// See 9.8.1.8 for the description of the behaviour of this operation
		
		ParameterSettingSeqType getSystemSWSettings(
			in ManagedEntityIdType nEManagedEntityId)
			raises (AccessDenied, UnknownManagedEntity);
	
	}; // interface ImpairmentPersistence

	
	interface ReportController : itut_x780::ManagedObject {
	
		// See 9.8.2.1 for the description of the behaviour of this operation
		
		void addCustomerMonitoringReporting  (
			in ManagedEntityIdType nEManagedEntityId,
			in ServiceInstanceIdType serviceInstanceId,
			in ManagedEntityIdType monitoringPoint,
			in GeneralizedTimeType stopTime,
			in HistoryDataType historyData,
			in short granularityPeriod) //in minutes
			raises (UnknownServiceInstance,
				AccessDenied,
				UnknownNE,
				UnknownManagedEntity,
				CollectionPeriodPast,
				CollectionLimitation,
				InvalidAssociation,
				UnknownHistoryDataType,
				CommFailure);
			
		// See 9.8.2.2 for the description of the behaviour of this operation
		
		void removeCustomerMonitoringReporting  (
			in ServiceInstanceIdType serviceInstanceId)
			raises (UnknownServiceInstance,
				AccessDenied,
				CollectionPeriodPast,
				CommFailure);

		// See 9.8.2.3 for the description of the behaviour of this operation
		
		RecordsSeqType selectByServiceInstance (
			in ServiceInstanceIdType serviceInstanceId,
			in GeneralizedTimeType intervalStartTime,
			in GeneralizedTimeType intervalEndTime)
			raises (UnknownServiceInstance,
				AccessDenied );
		
		// See 9.8.2.4 for the description of the behaviour of this operation
		
		MonitoringPointSeqType displayActiveReporting (
			in ServiceInstanceIdType serviceInstanceId)
			raises (UnknownServiceInstance,
				AccessDenied);

		// See 9.8.2.5 for the description of the behaviour of this operation
		
		void addNewMonitoringReporting (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in GeneralizedTimeType stopTime,
			in HistoryDataType historyData,
			in short granularityPeriod) //in minutes
			raises (AccessDenied,
				UnknownNE,
				UnknownManagedEntity,
				CollectionPeriodPast,
				CollectionLimitation,
				InvalidAssociation,
				UnknownHistoryDataType,
				CommFailure);
		
		// See 9.8.2.6 for the description of the behaviour of this operation
		
		RecordsSeqType selectByMonitoringPoint (
			in ManagedEntityIdType monitoringPoint,
			in GeneralizedTimeType intervalStartTime,
			in GeneralizedTimeType intervalEndTime)
			raises (UnknownManagedEntity,
				AccessDenied);
		
		
		// See 9.8.2.7 for the description of the behaviour of this operation
		
		void createReportingSchedule (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in HistoryDataType historyData,
			in ServiceInstanceIdType serviceInstance,
			in short granularityPeriod, //in minutes
			in UserLabelType schedulerName)
			raises (AccessDenied, 
				UnknownNE, 
				UnknownManagedEntity,
				CollectionLimitation,
				UnknownScheduler,
				InvalidAssociation,
				UnknownHistoryDataType,
				InvalidScheduler);
		 
		// See 9.8.2.8 for the description of the behaviour of this operation
		
		void modifyReportingSchedule (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in HistoryDataType historyData,
			in UserLabelType newSchedulerName)
			raises (AccessDenied,
				UnknownNE,
				UnknownManagedEntity,
				CollectionLimitation,
				UnknownScheduler,
				InvalidAssociation,
				UnknownHistoryDataType,
				InvalidScheduler); 
		
		// See 9.8.2.9 for the description of the behaviour of this operation
		
		void cancelReportingSchedule (
			in ManagedEntityIdType nEManagedEntityId,
			in ManagedEntityIdType monitoringPoint,
			in HistoryDataType historyData,
			in UserLabelType schedulerName)
			raises (AccessDenied,
				UnknownNE,
				UnknownManagedEntity,
				UnknownScheduler,
				InvalidAssociation,
				UnknownHistoryDataType);
	
	}; // interface ReportController
	
}; // module PerformanceManager

}; // module q834_4

#endif