-- IDL module extracted from ITU-T Q.822.1 (10/2001)

#ifndef _itut_q822_1_idl_
#define _itut_q822_1_idl_


#include <itut_x780.idl>
#include <itut_x780_1.idl>
#include <itut_x780ct.idl>
#include <itut_q816.idl>
#include <itut_q816_1.idl>
#include <itut_m3120.idl>


#pragma prefix "itu.int"


/**
This IDL code is intended to be stored in a file named "itut_q822_1.idl"
located in the search path used by IDL compilers installed on your system.
*/


/**
This module, itut_q822d1, contains IDL definition based on objects defined 
in ITU-T Rec. Q.822. The IDL definitions in this file are the object interfaces.
*/
module itut_q822d1
{


/**
5.1	Imports

*/

/**
Types imported from itut_x780
*/
	typedef itut_x780::AdministrativeStateType AdministrativeStateType;
	typedef itut_x780::DeletePolicyType DeletePolicyType;
	typedef itut_x780::GeneralizedTimeType GeneralizedTimeType;
	typedef itut_x780::Istring Istring;
	typedef itut_x780::IstringSetType IstringSetType;
	typedef itut_x780::MONameType MONameType;
	typedef itut_x780::MONameSetType MONameSetType;
	typedef itut_x780::NameBindingType NameBindingType;
	typedef itut_x780::OperationalStateType OperationalStateType;
	typedef itut_x780::PerceivedSeverityType PerceivedSeverityType;
	typedef itut_x780::ScopedNameSetType ScopedNameSetType;
	typedef itut_x780::UIDType UIDType;


/**
Types imported from itut_x780ct
*/
	typedef itut_x780ct::SeverityIndicatingThresholdType
		SeverityIndicatingThresholdType;
	typedef itut_x780ct::SeverityIndicatingGaugeThresholdSetType
		SeverityIndicatingGaugeThresholdSetType;
	typedef itut_x780ct::TimeIntervalType TimeIntervalType;
	typedef itut_x780ct::TimePeriodType TimePeriodType;


/**
Types imported from itut_q816
*/
	typedef itut_q816::ScopeType ScopeType;
	typedef itut_q816::FilterType FilterType;
	typedef itut_q816::LanguageType LanguageType;


/**
Types imported from itut_m3120
*/
	typedef itut_m3120::ManagedElementNameType ManagedElementNameType;
/**
Interfaces imported from itut_x780

itut_x780::ManagedObject
itut_x780::ManagedObjectFactory
*/


/**
5.2	Forward Declarations

*/

/**
Interface forward declarations
*/
	interface Scanner;
	interface HistoryDataIterator;
	interface CurrentData;
	interface ThresholdData;
	interface HDFile;
	interface AbstractHDScanner;
	interface ListHDScanner;
	interface ClassHDScanner;
	interface ScopedFiltedHDScanner;


/**
Valuetype forward declarations
*/
	valuetype ScannerValueType;
	valuetype CurrentDataValueType;
	valuetype HistoryDataValueType;
	valuetype ThresholdDataValueType;
	valuetype HDFileValueType;
	valuetype AbstractHDScannerValueType;
	valuetype ListHDScannerValueType;
	valuetype ClassHDScannerValueType;
	valuetype ScopedFiltedHDScannerValueType;


/**
Interface forward declarations
*/
	typedef MONameType ScannerNameType;
	typedef MONameType CurrentDataNameType;
	typedef MONameType ThresholdDataNameType;
	typedef MONameType HDFileNameType;
	typedef MONameType AbstractHDScannerNameType;
	typedef MONameType ListHDScannerNameType;
	typedef MONameType ClassHDScannerNameType;
	typedef MONameType ScopedFiltedHDScannerNameType;


/**
5.3	Structures and Typedefs

*/

/**
This data type defines a sequence of HistoryDataValueType. The order is significant.
*/
	typedef sequence <HistoryDataValueType> HistoryDataSeqValueType;

	typedef sequence <CurrentDataNameType> CurrentDataNameSetType;

	typedef UIDType HDFileFormatType;

	typedef sequence <HDFileFormatType> HDFileFormatSetType;

	typedef Istring URLType;

	struct CounterThresholdSettingType 
	{
		string						attributeName;
		SeverityIndicatingThresholdType	threshold;
	};

/**
The order is insignificant.
*/
	typedef sequence <CounterThresholdSettingType> CounterThresholdSetType;

	struct GaugeThresholdSettingType
	{
		string 					attributeName;
		SeverityIndicatingGaugeThresholdSetType threshold;
	};

/**
The order is insignificant.
*/
	typedef sequence<GaugeThresholdSettingType> 
		GaugeThresholdSetType;

/**
This data structure represents all the CurrentData classes contained by a containing object through either direct or indirect containment.
*/
	struct CDClassSelectionType
	{
		MONameType		containingObject;
		ScopedNameSetType		cdClassList;
	};

	typedef sequence<CDClassSelectionType> CDClassSelectionSetType;


/**
5.4	Exceptions

*/

/**
Exceptions and Constants for Conditional Package
*/
	exception NOcounterThresholdListPackage {};

	exception NOdeleteNotificationPackage {};
	
	exception NOgaugeThresholdListPackage {};
	
	exception NOperiodSynchronizationPackage {};

	exception NOthresholdPackage {};


	const string counterThresholdListPackage =
		"itut_q822d1::counterThresholdListPackage";
	const string deleteNotificationPackage =
		"itut_q822d1::deleteNotificationPackage";
	const string gaugeThresholdListPackage =
		"itut_q822d1::gaugeThresholdListPackage";
	const string periodSynchronizationPackage =
		"itut_q822d1::periodSynchronizationPackage";
	const string thresholdPackage =
		"itut_q822d1::thresholdPackage";


/**
Exceptions for Performance Management
*/


/**
5.5	Interfaces – Fine-grained

*/

/**
5.5.1	Scanner

See 4.3.1 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- periodSynchronizationPackage: present if configurable agent internal synchronization of repeating time periods is required.

The Scanner interface is not instantiable.
*/
	valuetype ScannerValueType: itut_x780::ManagedObjectValueType
	{
		public AdministrativeStateType	administrativeState;
			// GET-REPLACE
		public OperationalStateType		operationalState;
			// GET
		public TimePeriodType			granularityPeriod;
			// GET-REPLACE
		public GeneralizedTimeType 		periodSynchronizationTime;
			// conditional
			// periodSynchronizationPackage
			// GET-REPLACE
	}; // valuetype ScannerValueType


	interface Scanner: itut_x780::ManagedObject
	{
		AdministrativeStateType administrativeStateGet ()
			raises (itut_x780::ApplicationError);

		void administrativeStateSet
			(in AdministrativeStateType administrativeState)
			raises (itut_x780::ApplicationError);

		OperationalStateType operationalStateGet ()
			raises (itut_x780::ApplicationError);

		TimePeriodType granularityPeriodGet ()
			raises (itut_x780::ApplicationError);

		void granularityPeriodSet
			(in TimePeriodType granularityPeriod)
			raises (itut_x780::ApplicationError);

		GeneralizedTimeType periodSynchronizationTimeGet ()
			raises (itut_x780::ApplicationError,
				NOperiodSynchronizationPackage);

		void periodSynchronizationTimeSet
			(in GeneralizedTimeType periodSyncTime)
			raises (itut_x780::ApplicationError,
				NOperiodSynchronizationPackage);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectCreation,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, attributeValueChange,
			attributeValueChangeNotificationPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, stateChange,
			stateChangeNotificationPackage)

	};  // interface Scanner


/**
5.5.2	CurrentData

See 4.3.2.1 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- thresholdPackage: present if a Quality of Service Alarm Notification is to be emitted for threshold crossing.

- zeroSupressionPackage: present if an instance supports it.

The CurrentData interface is not instantiable.
*/

/**
5.5.2.1	CurrentDataValueType

*/
	valuetype CurrentDataValueType: ScannerValueType
	{
		public boolean				suspectIntervalFlag;
			// GET REPLACE-WITH-DEFAULT
		public TimeIntervalType		elapsedTime;
			// GET
		public short 				historyRetention;
			// Mandatory now (used to be conditional)
			// GET-REPLACE
		public MONameSetType		thresholdDataInstanceList;
			// conditional
			// thresholdPackage
			// GET-REPLACE ADD-REMOVE
		public short				numSuppressedIntervals;
			// conditional
			// zeroSuppressionPackage
			// GET
		public short				maxSuppressedIntervals;
			// conditional
			// zeroSuppressionPackage
			// GET-REPLACE
	}; // valuetype CurrentDataValueType


/**
5.5.2.2	HistoryDataValueType

See 4.3.2.2 for behaviour.
*/
	valuetype HistoryDataValueType
	{
		public GeneralizedTimeType	periodEndTime;
			// GET
		public TimePeriodType		granularityPeriod;
			// GET
		public boolean				suspectIntervalFlag;
			// GET
		public short				numSupressedIntevals;
			// GET
	}; // valuetype HistoryDataValueType


/**
5.5.2.3	HistoryDataIterator

HistoryDataIterator is used for iteratively transferring a large chunk of
history data.
*/
	interface HistoryDataIterator
	{
/**
This method is used to return the next howMany history data. howMany is the maximum number of history data for which results should be returned in the first batch; it must be non-zero. historyDataList is a sequence of history data records. 
The method will return true if there is data in out parameter, false otherwise.
*/
		boolean getNext
			(in unsigned short howMany,
			out HistoryDataSeqValueType historyDataList)
			raises (itut_x780::ApplicationError);

/**
This method is used to destroy the iterator and release its resources. This must be done by the application.
*/
		void destroy ();

	};  // interface HistoryDataIterator


/**
5.5.2.4	CurrentData

*/
	interface CurrentData: Scanner
	{
/**
Define default value for suspectIntervalFlag
*/
		const boolean suspectIntervalFlagDefault = FALSE;

/**
Define default value for maxSuppressedIntervals. The default value -1 means that there is no limit on the number of consecutive suppressed intervals. On the other hand, the maxSuppressedIntervals is effectively equal to infinity.
*/
		const short maxSuppressedIntervalsDefault = -1;

		boolean suspectIntervalFlagGet ()
			raises (itut_x780::ApplicationError);

		void suspectIntervalFlagDefaultSet
			(in boolean suspectIntervalFlag)
			raises (itut_x780::ApplicationError);

		TimeIntervalType elapsedTimeGet ()
			raises (itut_x780::ApplicationError);

		short historyRetentionGet ()
			raises (itut_x780::ApplicationError);

		void historyRetentionSet
			(in short intervalNum)
			raises (itut_x780::ApplicationError);

		MONameSetType thresholdDataInstanceListGet ()
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListSet
			(in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListAdd
			(in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListRemove
			(in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		boolean getMostRecent
			(out HistoryDataValueType historyData)
			raises (itut_x780::ApplicationError);

		HistoryDataSeqValueType getBetween
			(in GeneralizedTimeType startTime,
			in GeneralizedTimeType endTime,
			in unsigned short howMany,
			out HistoryDataIterator resultIterator)
			raises (itut_x780::ApplicationError);

/**
*/
		short numSuppressedIntervalsGet ()
			raises (itut_x780::ApplicationError);

		short maxSuppressedIntervalsGet ()
			raises (itut_x780::ApplicationError);

		void maxSuppressedIntervalsSet
			(in short maxSuppInterval)
			raises (itut_x780::ApplicationError);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, qualityOfServiceAlarm, 
			NOthresholdPackage)

	};  // interface CurrentData


/**
5.5.3	ThresholdData

See 4.3.3 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- counterThresholdListPackage: present if an instance supports it and the gaugeThresholdListPackage is not present.

- gaugeThresholdListPackage: present if an instance supports it and the counterThresholdListPackage is not present
*/
	valuetype ThresholdDataValueType: itut_x780::ManagedObjectValueType
	{
		public CounterThresholdSetType	counterThresholdList;
			// conditional
			// counterThresholdListPackage
			// GET-REPLACE ADD-REMOVE
		public GaugeThresholdSetType	gaugeThresholdList;
			// conditional
			// gaugeThresholdListPackage
			// GET-REPLACE ADD-REMOVE
	}; // valuetype ThresholdDataValueType


	interface ThresholdData: itut_x780::ManagedObject
	{
		CounterThresholdSetType counterThresholdListGet ()
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListSet
			(in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListAdd
			(in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListRemove
			(in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		GaugeThresholdSetType gaugeThresholdListGet ()
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListSet
			(in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListAdd
			(in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListRemove
			(in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectCreation,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, attributeValueChange,
			attributeValueChangeNotificationPackage)

	};  // interface ThresholdData 


	interface ThresholdDataFactory: itut_x780::ManagedObjectFactory
	{
		itut_x780::ManagedObject create
			(in NameBindingType nameBinding,
			in MONameType superior,
			in string reqID,	// auto naming if null
			out MONameType name,
			in IstringSetType packageNameList,
			in CounterThresholdSetType counterThresholdList,
				// conditional
				// counterThresholdListPackage
				// GET-REPLACE ADD-REMOVE
			in GaugeThresholdSetType gaugeThresholdList)
				// conditional
				// gaugeThresholdListPackage
				// GET-REPLACE ADD-REMOVE
			raises (itut_x780::ApplicationError, 
				itut_x780::CreateError);
		
	}; // interface ThresholdDataFactory


/**
5.5.4	HDFile (HistoryDataFile)

See 4.3.4 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- objectDeleteNotificationPackage: present if an instance supports it.
*/
	valuetype HDFileValueType: itut_x780::ManagedObjectValueType
	{
		public HDFileFormatType		fileFormat;
			// GET, SET-BY-CREATE
		public URLType			fileLocation;
			// GET, SET-BY-CTEATE
		public GeneralizedTimeType	periodEndTime;
			// GET, SET-BY-CREATE
		public TimePeriodType		fileRetentionDuration;
			// GET, SET-BY-CREATE
	}; // valuetype HDFileValueType


	interface HDFile: itut_x780::ManagedObject
	{
		HDFileFormatType fileFormatGet ()
			raises (itut_x780::ApplicationError);
	
		URLType fileLocationGet ()
			raises (itut_x780::ApplicationError);

		GeneralizedTimeType periodEndTimeGet ()
			raises (itut_x780::ApplicationError);

		TimePeriodType fileRetentionDurationGet ()
			raises (itut_x780::ApplicationError);

		MANDATORY_NOTIFICATION(
			itut_x780::Notifications, objectCreation)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			deleteNotificationPackage)

	}; // interface HDFile


	interface HDFileFactory: itut_x780::ManagedObjectFactory
	{
		itut_x780::ManagedObject create
			(in NameBindingType nameBinding,
			in MONameType superior,
			in string reqID, // auto naming if empty string
			out MONameType name,
			in HDFileFormatType fileFormat,
			in URLType fileLocation,
			in GeneralizedTimeType periodEndTime,
			in TimePeriodType fileRetentionDuration)
			raises (itut_x780::ApplicationError,
				itut_x780::CreateError);

	}; // interface HDFileFactory


/**
5.5.5	AbstractHDScanner (AbstractHistoryDataScanner)

See 4.3.5 for behaviour.
*/
	valuetype AbstractHDScannerValueType: ScannerValueType
	{
		public HDFileFormatSetType	supportedFileFormatList;
			// GET
		public HDFileFormatType		hdFileFormat;
			// GET, SET
		public TimePeriodType		hdFileRetentionDuration;
			// GET, SET
		public TimePeriodType		beginRelativeTime;
			// GET, SET
		public TimePeriodType		endRelativeTime;
			// GET, SET
	}; // valuetype HDScannerValueType


	interface AbstractHDScanner: Scanner
	{

		HDFileFormatSetType supportedFileFormatListGet ()
			raises (itut_x780::ApplicationError);
			
/**
The hdFileFormat must be one of the supported file formats.
*/
		HDFileFormatType hdFileFormatGet ()
			raises (itut_x780::ApplicationError);
	
		void hdFileFormatSet
			(in HDFileFormatType hdFileFormat)
			raises (itut_x780::ApplicationError);

		TimePeriodType hdFileRetentionDurationGet ()
			raises (itut_x780::ApplicationError);

		void hdFileRetentionDurationSet
			(in TimePeriodType hdFileRetentionDuration)
			raises (itut_x780::ApplicationError);

		TimePeriodType beginRelativeTimeGet ()
			raises (itut_x780::ApplicationError);

		void beginRelativeTimeSet
			(in TimePeriodType beginRelativeTime)
			raises (itut_x780::ApplicationError);

		TimePeriodType endRelativeTimeGet ()
			raises (itut_x780::ApplicationError);

		void endRelativeTimeSet
			(in TimePeriodType endRelativeTime)
			raises (itut_x780::ApplicationError);

		HistoryDataSeqValueType returnHDReport
			(in unsigned short howMany,
			out HistoryDataIterator resultIterator)
			raises (itut_x780::ApplicationError);

		void generateHDFileNow ()
			raises (itut_x780::ApplicationError);	

	};  // interface AbstractHDScanner


/**
5.5.6	ListHDScanner

See 4.3.6 for behaviour.
*/
	valuetype ListHDScannerValueType: AbstractHDScannerValueType
	{
		public CurrentDataNameSetType	cdInstanceList;
			// GET, SET
	}; // valuetype ListHDScannerValueType


	interface ListHDScanner: AbstractHDScanner
	{
		CurrentDataNameSetType cdInstanceListGet ()
			raises (itut_x780::ApplicationError);

		void cdInstanceListSet
			(in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

		void cdInstanceListAdd
			(in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

		void cdInstanceListRemove
			(in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

	}; // interface ListHDScanner


	interface ListHDScannerFactory: itut_x780::ManagedObjectFactory
	{
		itut_x780::ManagedObject create
			(in NameBindingType nameBinding,
			in MONameType superior,
			in string reqID, // auto naming if empty string
			out MONameType name,
			in CurrentDataNameSetType cdInstanceList,
			in HDFileFormatType fileFormat,
			in TimePeriodType fileRetentionDuration,
			in TimePeriodType beginRelativeTime,
			in TimePeriodType endRelativeTime,
			in AdministrativeStateType administrativeState,
			in TimePeriodType granularityPeriod,
			in GeneralizedTimeType periodSynchronizationTime)
				// conditional
				// periodSynchronizationPackage
			raises (itut_x780::ApplicationError,
				itut_x780::CreateError);

	};  // interface ListHDScannerFactory


/**
5.5.7	ClassHDScanner

See 4.3.7 for behaviour.
*/
	valuetype ClassHDScannerValueType: AbstractHDScannerValueType
	{
		public CDClassSelectionSetType	cdClassSelectionList;
			// GET, SET
	}; // valuetype ClassHDScannerValueType


	interface ClassHDScanner: AbstractHDScanner
	{
		CDClassSelectionSetType cdClassSelectionListGet ()
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListSet
			(in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListAdd
			(in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListRemove
			(in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

	}; // interface ClassHDScanner


	interface ClassHDScannerFactory: itut_x780::ManagedObjectFactory
	{
		itut_x780::ManagedObject create
			(in NameBindingType nameBinding,
			in MONameType superior,
			in string reqID, // auto naming if empty string
			out MONameType name,
			in CDClassSelectionSetType cdClassSelectionList,
			in HDFileFormatType fileFormat,
			in TimePeriodType fileRetentionDuration,
			in TimePeriodType beginRelativeTime,
			in TimePeriodType endRelativeTime,
			in AdministrativeStateType administrativeState,
			in TimePeriodType granularityPeriod,
			in GeneralizedTimeType periodSynchronizationTime)
				// conditional
				// periodSynchronizationPackage
			raises (itut_x780::ApplicationError,
				itut_x780::CreateError);

	};  // interface ClassHDScannerFactory


/**
5.5.8	ScopedFilteredHDScanner

See 4.3.8 for behaviour.
*/
	valuetype ScopedFiltedHDScannerValueType: AbstractHDScannerValueType
	{
		public MONameType		base;
			// GET, SET
		public ScopeType		scope;
			// GET, SET
		public FilterType		filter;
			// GET, SET
		public LanguageType	language;
			// GET, SET
	}; // valuetype ScopedFiltedHDScannerValueType


	interface ScopedFiltedHDScanner: AbstractHDScanner
	{
		MONameType baseGet ()
			raises (itut_x780::ApplicationError);

		void baseSet
			(in MONameType base)
			raises (itut_x780::ApplicationError);

		ScopeType scopeGet ()		
			raises (itut_x780::ApplicationError);

		void scopeSet
			(in ScopeType scope)
			raises (itut_x780::ApplicationError);

		FilterType filterGet ()
			raises (itut_x780::ApplicationError);

		void filterSet
			(in FilterType filter)
			raises (itut_x780::ApplicationError);

		LanguageType languageGet ()
			raises (itut_x780::ApplicationError);

		void languageSet
			(in LanguageType language)
			raises (itut_x780::ApplicationError);

	}; // interface ScopedFiltedHDScanner


	interface ScopedFiltedHDScannerFactory:
		itut_x780::ManagedObjectFactory
	{
		itut_x780::ManagedObject create
			(in NameBindingType nameBinding,
			in MONameType superior,
			in string reqID, // auto naming if empty string
			out MONameType name,
			in MONameType base,
			in ScopeType scope,
			in FilterType filter,
			in LanguageType language,
			in HDFileFormatType fileFormat,
			in TimePeriodType fileRetentionDuration,
			in TimePeriodType beginRelativeTime,
			in TimePeriodType endRelativeTime,
			in AdministrativeStateType administrativeState,
			in TimePeriodType granularityPeriod,
			in GeneralizedTimeType periodSynchronizationTime)
				// conditional
				// periodSynchronizationPackage
			raises (itut_x780::ApplicationError,
				itut_x780::CreateError);

	};  // interface ScopedFiltedHDScannerFactory


/**
5.6	Interfaces – Facade

The facade history data scanners are defined here as per ITU-T Rec. X.780.1. However the fine-grained history data scanners would be sufficient for facade implementation.
*/

/**
5.6.1	Scanner_F

See 4.3.1 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- periodSynchronizationPackage: present if configurable agent internal synchronization of repeating time periods is required.

The Scanner interface is not instantiable.
*/
	interface Scanner_F: itut_x780::ManagedObject_F
	{
		AdministrativeStateType administrativeStateGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void administrativeStateSet
			(in MONameType name,
			in AdministrativeStateType administrativeState)
			raises (itut_x780::ApplicationError);

		OperationalStateType operationalStateGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		TimePeriodType granularityPeriodGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void granularityPeriodSet
			(in MONameType name,
			in TimePeriodType granularityPeriod)
			raises (itut_x780::ApplicationError);

		GeneralizedTimeType periodSynchronizationTimeGet
			(in MONameType name)
			raises (itut_x780::ApplicationError,
				NOperiodSynchronizationPackage);

		void periodSynchronizationTimeSet
			(in MONameType name,
			in GeneralizedTimeType periodSyncTime)
			raises (itut_x780::ApplicationError,
				NOperiodSynchronizationPackage);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectCreation,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, attributeValueChange,
			attributeValueChangeNotificationPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, stateChange,
			stateChangeNotificationPackage)

	};  // interface Scanner_F


/**
5.6.2	CurrentData_F

See 4.3.2.1 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- thresholdPackage: present if a Quality of Service Alarm Notification is to be emitted for threshold crossing.

- zeroSupressionPackage: present if an instance supports it.

The CurrentData interface is not instantiable.
*/
	interface CurrentData_F: Scanner_F
	{
/**
Define default value for suspectIntervalFlag
*/
		const boolean suspectIntervalFlagDefault = FALSE;

/**
Define default value for maxSuppressedIntervals. The default value -1 means that there is no limit on the number of consecutive suppressed intervals. On the other hand, the maxSuppressedIntervals is effectively equal to infinity.
*/
		const short maxSuppressedIntervalsDefault = -1;

		boolean suspectIntervalFlagGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void suspectIntervalFlagDefaultSet
			(in MONameType name,
			in boolean suspectIntervalFlag)
			raises (itut_x780::ApplicationError);

		TimeIntervalType elapsedTimeGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		short historyRetentionGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void historyRetentionSet
			(in MONameType name,
			in short intervalNum)
			raises (itut_x780::ApplicationError);

		MONameSetType thresholdDataInstanceListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListSet
			(in MONameType name,
			in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListAdd
			(in MONameType name,
			in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		void thresholdDataInstanceListRemove
			(in MONameType name,
			in MONameSetType dataInstanceList)
			raises (itut_x780::ApplicationError,
				NOthresholdPackage);

		boolean getMostRecent
			(in MONameType name,
			out HistoryDataValueType historyData)
			raises (itut_x780::ApplicationError);

		HistoryDataSeqValueType getBetween
			(in MONameType name,
			in GeneralizedTimeType startTime,
			in GeneralizedTimeType endTime,
			in unsigned short howMany,
			out HistoryDataIterator resultIterator)
			raises (itut_x780::ApplicationError);

		short numSuppressedIntervalsGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		short maxSuppressedIntervalsGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void maxSuppressedIntervalsSet
			(in MONameType name,
			in short maxSuppInterval)
			raises (itut_x780::ApplicationError);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, qualityOfServiceAlarm, 
			NOthresholdPackage)

	};  // interface CurrentData_F


/**
5.6.3	ThresholdData_F

See 4.3.3 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- counterThresholdListPackage: present if an instance supports it and the gaugeThresholdListPackage is not present.

- gaugeThresholdListPackage: present if an instance supports it and the counterThresholdListPackage is not present.
*/
	interface ThresholdData_F: itut_x780::ManagedObject_F
	{
		CounterThresholdSetType counterThresholdListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListSet
			(in MONameType name,
			in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListAdd
			(in MONameType name,
			in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		void counterThresholdListRemove
			(in MONameType name,
			in CounterThresholdSetType counterThresholdList)
			raises (itut_x780::ApplicationError,
				NOcounterThresholdListPackage);

		GaugeThresholdSetType gaugeThresholdListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListSet
			(in MONameType name,
			in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListAdd
			(in MONameType name,
			in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		void gaugeThresholdListRemove
			(in MONameType name,
			in GaugeThresholdSetType gaugeThresholdList)
			raises (itut_x780::ApplicationError,
				NOgaugeThresholdListPackage);

		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectCreation,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			createDeleteNotificationsPackage)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, attributeValueChange,
			attributeValueChangeNotificationPackage)

	};  // interface ThresholdData_F 


/**
5.6.4	HDFile_F (HistoryDataFile)

See 4.3.4 for behaviour.

This interface contains the following CONDITIONAL PACKAGES.

- objectDeleteNotificationPackage: present if an instance supports it.
*/
	interface HDFile_F: itut_x780::ManagedObject_F
	{
		HDFileFormatType fileFormatGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);
	
		URLType fileLocationGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		GeneralizedTimeType periodEndTimeGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		TimePeriodType fileRetentionDurationGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		MANDATORY_NOTIFICATION(
			itut_x780::Notifications, objectCreation)
		CONDITIONAL_NOTIFICATION(
			itut_x780::Notifications, objectDeletion,
			deleteNotificationPackage)

	}; // interface HDFile_F


/**
5.6.5	AbstractHDScanner_F (AbstractHistoryDataScanner)

See 4.3.5 for behaviour.
*/
	interface AbstractHDScanner_F: Scanner_F
	{

		HDFileFormatSetType supportedFileFormatListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);
			
/**
The hdFileFormat must be one of supported file format.
*/
		HDFileFormatType hdFileFormatGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);
	
		void hdFileFormatSet
			(in MONameType name,
			in HDFileFormatType hdFileFormat)
			raises (itut_x780::ApplicationError);

		TimePeriodType hdFileRetentionDurationGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void hdFileRetentionDurationSet
			(in MONameType name,
			in TimePeriodType hdFileRetentionDuration)
			raises (itut_x780::ApplicationError);

		TimePeriodType beginRelativeTimeGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void beginRelativeTimeSet
			(in MONameType name,
			in TimePeriodType beginRelativeTime)
			raises (itut_x780::ApplicationError);

		TimePeriodType endRelativeTimeGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void endRelativeTimeSet
			(in MONameType name,
			in TimePeriodType endRelativeTime)
			raises (itut_x780::ApplicationError);

		HistoryDataSeqValueType returnHDReport
			(in MONameType name,
			in unsigned short howMany,
			out HistoryDataIterator resultIterator)
			raises (itut_x780::ApplicationError);

		void generateHDFileNow
			(in MONameType name)
			raises (itut_x780::ApplicationError);	

	};  // interface AbstractHDScanner_F


/**
5.6.6	ListHDScanner_F

See 4.3.6 for behaviour.
*/
	interface ListHDScanner_F: AbstractHDScanner_F
	{
		CurrentDataNameSetType cdInstanceListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void cdInstanceListSet
			(in MONameType name,
			in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

		void cdInstanceListAdd
			(in MONameType name,
			in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

		void cdInstanceListRemove
			(in MONameType name,
			in CurrentDataNameSetType instanceList)
			raises (itut_x780::ApplicationError);

	}; // interface ListHDScanner_F


/**
5.6.7	ClassHDScanner_F

See 4.3.7 for behaviour.
*/
	interface ClassHDScanner_F: AbstractHDScanner_F
	{
		CDClassSelectionSetType cdClassSelectionListGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListSet
			(in MONameType name,
			in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListAdd
			(in MONameType name,
			in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

		void cdClassSelectionListRemove
			(in MONameType name,
			in CDClassSelectionSetType classList)
			raises (itut_x780::ApplicationError);

	}; // interface ClassHDScanner_F


/**
5.6.8	ScopedFilteredHDScanner_F

See 4.3.8 for behaviour.
*/
	interface ScopedFiltedHDScanner_F: AbstractHDScanner_F
	{
		MONameType baseGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void baseSet
			(in MONameType name,
			in MONameType base)
			raises (itut_x780::ApplicationError);

		ScopeType scopeGet
			(in MONameType name)		
			raises (itut_x780::ApplicationError);

		void scopeSet
			(in MONameType name,
			in ScopeType scope)
			raises (itut_x780::ApplicationError);

		FilterType filterGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void filterSet
			(in MONameType name,
			in FilterType filter)
			raises (itut_x780::ApplicationError);

		LanguageType languageGet
			(in MONameType name)
			raises (itut_x780::ApplicationError);

		void languageSet
			(in MONameType name,
			in LanguageType language)
			raises (itut_x780::ApplicationError);

	}; // interface ScopedFiltedHDScanner_F


/**
5.7	Notifications

No model specific notifications defined in this Recommendation.
*/


/**
5.8	Name Binding

*/

/**
The following module contains name-binding information.
*/
	module NameBinding
	{


/**
5.8.1	ThresholdData

This name binding is used to name the ThresholdData object to a Managed Element object.
*/
		module ThresholdData_ManagedElement
		{
			const string	superiorClass =
				"itut_m3120::ManagedElement";
			const boolean	superiorSubclassesAllowed = TRUE;
			const string	subordinateClass =
				"itut_q822d1::ThresholdData";
			const boolean	subordinateSubclassesAllowed = TRUE;
			const boolean	managerCreatesAllowed = TRUE;
			const DeletePolicyType deletePolicy =
				itut_x780::deleteOnlyIfNoContainedObjects;
			const string	kind = "ThresholdData";
		}; // module ThresholdData_ManagedElement


/**
5.8.2	HDFile

This name binding is used to name the HDFile object to an AbstractHDScanner object.
*/
		module HDFile_AbstractHDScanner
		{
			const string	superiorClass =
				"itut_q822d1::AbstractHDScanner";
			const boolean	superiorSubclassesAllowed = TRUE;
			const string	subordinateClass =
				"itut_q822d1::HDFile";
			const boolean	subordinateSubclassesAllowed = TRUE;
			const boolean	managerCreatesAllowed = FALSE;
			const DeletePolicyType deletePolicy =
				itut_x780::deleteOnlyIfNoContainedObjects;
			const string	kind = "HDFile";
		}; // module HDFile_AbstractHDScanner


/**
5.8.3	AbstractHDScanner

This name binding is used to name the AbstractHDScanner object to a ManagedElement.
*/
		module AbstractHDScanner_ManagedElement
		{
			const string	superiorClass =
				"itut_m3120::ManagedElement";
			const boolean	superiorSubclassesAllowed = TRUE;
			const string	subordinateClass =
				"itut_q822d1::AbstractHDScanner";
			const boolean	subordinateSubclassesAllowed = TRUE;
			const boolean	managerCreatesAllowed = TRUE;
			const DeletePolicyType deletePolicy =
				itut_x780::deleteOnlyIfNoContainedObjects;
			const string	kind = "HDScanner";
		}; // module AbstractHDScanner_ManagedElement


	}; // module NameBinding


/**
5.9	HDFileFormatConst

This module contains constant values identifying history data file formats.
*/
	module HDFileFormatConst
	{
		const string moduleName =
			"itut_q822d1::HDFileFormatConst";

		const short unknown = 0;

		const short q822d1FileText = 1;

		const short q822d1FileXML = 2;

	}; // HDFileFormatConst


}; // module itut_q822d1




#endif // _itut_q822_1_idl